Tutoriel Excel : la fonction CHOISIR avec des exemples
Rédigé par Hanane Mouqqadim, Publié le 18 Août 2020, Mise à jour le Dimanche, 13 Décembre 2020 05:32![](/images/thumb/29/id-3445.png)
Ce tutoriel explique la syntaxe de la fonction CHOISIR dans Excel, et vous donne des exemples de ses utilisations de base. Vous apprendrez également comment utiliser la fonction CHOISIR en combinaison avec d’autres fonctions et formules avancées Excel.
Excel dispose de plusieurs fonctions que vous pouvez voir inutiles, dont la fonction CHOISIR. Cependant, lorsque vous la combiner avec d’autres formules, vous allez pouvoir découvrir plusieurs avantages impressionnants qui démontrent la puissance de cette simple petite fonction. Allons-y vite explorer comment appliquer la fonction CHOISIR avec quelques exemples pratiques. Suivez le tutoriel !
Table des matières
La fonction CHOISIR dans Excel - syntaxe et utilisations de base
La fonction CHOISIR dans Excel - choses à retenir !
Comment utiliser la fonction CHOISIR dans Excel - Exemples de formules
Renvoyer différentes valeurs en fonction de la condition
Effectuer différents calculs en fonction d’une condition
Exemple 3 : utiliser la fonction CHOISIR pour faire une RECHERCHEV gauche
La fonction CHOISIR dans Excel - syntaxe et utilisations de base
La fonction CHOISIR est utilisée pour trouver une valeur dans une plage de cellules donnée en fournissant la position de cette valeur.
La syntaxe de la fonction CHOISIR est comme suit :
CHOISIR(no_index ; valeur1 ; [Valeur2] ; …)
Où :
- « No_index » : il s’agit d’un argument requis par la fonction, et peut être une valeur numérique comprise entre 1 et 254 comme « 1 » ou « 2 », une référence de cellule ou une autre formule. Cet argument représente la position ou l’index de la valeur à retourner par la fonction CHOISIR.
- « Valeur1 » : c’est un argument obligatoire qui peut être une chaine de texte, un nombre, une référence de cellule ou une autre fonction.
- « [Valeur2] » : cet argument et les arguments suivants sont facultatifs. Ils peuvent également être des chaines de texte, des références de cellules, des nombres ou des fonctions. En fait, les arguments de valeurs font référence à la liste des valeurs dans lesquelles la fonction doit effectuer la recherche.
Voici un exemple pour solidifier votre compréhension de la fonction CHOISIR.
Dans l’exemple ci-dessous, nous allons utiliser la fonction CHOISIR pour retourner le nom du mois en fournissant la valeur numérique de ce mois.
Par exemple, si nous donnons la valeur « 7 » comme argument « no_index » et la liste des mois dans les arguments de valeurs, la fonction retournera « Juillet ».
Pour réaliser cette tâche, nous allons appliquer la formule ci-dessous :
=CHOISIR(7; "Janvier"; "Février"; "Mars"; "Avril"; "Mai"; "Juin"; "Juillet"; "Aout"; "septembre"; "Octobre"; "Novembre"; "Décembre")
Si, à la place de « 7 », nous avons écrit « 1 » comme valeur de « no_index », la formule retournera « Janvier » puisqu’il s’agit du 1er mois de la liste.
De même, si nous donnons « 5 », elle retournera le mois « Mai » puisque c’est le 5ème mois dans la liste.
Au lieu de coder en dur les noms des mois dans la formule, nous pouvons utiliser les références de cellules pour simplifier la tâche. Pour cela, nous allons mettre la liste des mois dans une plage de cellules, par exemple B2:B13 et leur valeurs numériques dans la colonne A comme illustré ci-dessous :
Maintenant, nous pouvons utiliser ces références de cellules à la place des valeurs littérales dans notre formule CHOISIR précédente. Le résultat sera donc comme suit :
=CHOISIR(A2; B2; B3; B4; B5; B6; B7; B8; B9; B10; B11; B12; B13)
N’oubliez pas que vous pouvez aussi utiliser une combinaison de références et de valeurs littérales. Ci-dessous un exemple de cette formule :
=CHOISIR(6; B2; "Février"; B4; B5; B6; B7; "Juillet"; B9; B10; B11; B12; B13)
La fonction CHOISIR dans Excel - choses à retenir !
La fonction CHOISIR est une fonction très simple dans son utilisation et vous ne rencontrerez pratiquement aucune difficulté à l'implémenter dans vos feuilles de calcul. Cependant, comme pour toute autre fonction Excel, vous pouvez vous retrouver dans des cas où le résultat renvoyé par votre formule CHOISIR est inattendu ou ne correspond pas au résultat recherché. En effet, cela peut être dû aux raisons suivantes :
- Si vous utilisez un très grand nombre de valeurs, la fonction CHOISIR ne fonctionnera pas. Le nombre de valeurs parmi lesquelles choisir est limité à 254.
- Le nombre de valeurs doit toujours être supérieur ou égal à « no_index ». S'il est inférieur à « no_index », la fonction renverra une erreur « #VALEUR ».
- Si vous utilisez une fraction dans l'argument « no_index », il sera tronqué au plus petit entier.
- Si l'argument « no_index » est inférieur à 1, la formule renvoie une erreur « #VALEUR! ».
- L’erreur « #NOM? » se produit lorsque vous utilisez des valeurs de texte dans les arguments de valeur et qui ne sont pas entre guillemets ou ne sont pas des références de cellules valides.
- La fonction CHOISIR ne récupérera pas la valeur d'une plage ou d'une constante de tableau (telle que A2:B10).
Comment utiliser la fonction CHOISIR dans Excel - Exemples de formules
Dans cette section, nous vous proposons des exemples des utilisations de la fonction CHOISIR dans Excel. Vous découvrirez également comment cette fonction peut être une solution alternative à des tâches courantes, même à celles qui sont considérées comme irréalisables par certains.
Exemple 1 : la fonction CHOISIR dans Excel renvoie un nom de jour/mois personnalisé à partir d’une date
Si vous souhaitez obtenir le nom de jour ou du mois à partir d’une date donnée, vous pouvez utiliser la fonction CHOISIR comme suit :
- Pour retourner le nom de jour à partir de la date contenue dans la cellule A2, utilisez la formule ci-dessous :
=CHOISIR(JOURSEM(A2); "Dimanche"; "Lundi"; "mardi"; "mercredi"; "Jeudi"; "vendredi"; "Samedi")
- Pour obtenir le nom du mois à partir de la date contenue dans la cellule A2, vous pouvez utiliser la formule ci-dessous :
=CHOISIR(MOIS(A2); "Janvier"; "Février"; "Mars"; "Avril"; "Mai"; "Juin"; "Juillet"; "Aout"; "septembre"; "Octobre"; "Novembre"; "Décembre")
Ici, A2 est la première cellule des dates ; vous pouvez la modifier selon votre besoin. Une fois vous avez entré les formules dans les cellules B2 et C2, vous pouvez les copier dans les autres cellules jusqu’à les dernière ligne (ligne 12 dans notre exemple).
Ainsi, vous allez obtenir un résultat comme illustré dans la capture d’écran ci-dessous :
Exemple 2 : la fonction CHOISIR renvoie une valeur basée sur des conditions (la meilleure alternative de la fonction SI imbriquée)
L’une des taches qu’on cherche à réaliser le plus souvent dans Excel est de retourner une valeur en se basant sur des conditions. Comme solution classique, nous utilisons dans la plupart des cas la formule conditionnelle SI. Cependant, l’utilisation de la fonction CHOISIR est une meilleure alternative qui vous permettra de réaliser ce genre de tache facilement et rapidement. Vous trouverez ci-dessous deux exemples pratiques de l’utilisation de la fonction CHOISIR comme alternative de la fonction SI imbriquée.
Renvoyer différentes valeurs en fonction de la condition
Dans cet exemple, nous avons des noms d’élèves dans la colonne A et leurs scores dans la colonne B, et nous souhaitons étiqueter les scores en fonction des conditions suivantes :
- SI le score est de 0 à 50 : « Faible ».
- Si le score est de 51 à 100 : « Satisfaisant ».
- Si le score est de 101 à 150 : « Bien ».
- Si le score est plus de 151 : « Excellent ».
La méthode classique de le faire consiste à utiliser des formules SI imbriquées les unes dans les autres comme suit :
=SI(B2> = 151; "Excellent"; SI(B2> = 101; "Bien"; SI(B2> = 51; "Satisfaisant"; "Faible")))
La solution alternative consiste à choisir une étiquette qui correspond à la condition en utilisant la formule CHOISIR ci-dessous :
=CHOISIR((B2>0) + (B2>51) + (B2>101) + (B2>151); "Faible"; "Satisfaisant"; "Bien"; "Excellent")
Comment fonctionne cette formule ?
- La fonction CHOISIR évalue chaque condition dans l'argument « no_index » et revoie la valeur « VRAI » si la condition est remplie, et la valeur « FAUX » dans le cas contraire. Par exemple, si la valeur de la cellule B2 remplit seulement la première condition, nous obtenons donc ce résultat intermédiaire :
=CHOISIR(VRAI + FAUX + FAUX + FAUX ; "Faible" ; "Satisfaisant" ; "Bien" ; "Excellent")
- Étant donné que dans la plupart des formules Excel, la valeur « VRAI » équivaut à « 1 » et « FAUX » équivaut à « », notre formule subit cette transformation :
=CHOISIR(1 + 0 + 0 + 0 ; "Faible" ; "Satisfaisant" ; "Bien" ; "Excellent")
- Ensuite, l'opération d'addition est effectuée et nous obtenons ce résultat :
=CHOISIR(1 ; "Faible" ; "Satisfaisant" ; "Bien" ; "Excellent")
- En conséquence, la 1ère valeur de la liste est renvoyée, qui est « Faible ».
Appliquez la formule au reste des cellules :
Vous pouvez rendre la formule plus flexible en utilisant des références de cellules au lieu d'étiquettes codées en dur. Par exemple, en mettant les étiquettes dans les cellules E2:E5, la formule devient :
=CHOISIR((B2> 0) + (B2> = 51) + (B2> = 101) + (B2> = 151); $E$2; $E$3; $E$4; $E$5)
Remarque :
- Si aucune de vos conditions n'est « VRAI », l'argument « no_index » sera mis à forçant votre formule à renvoyer l’erreur « #VALEUR! ». Pour éviter ce genre de problème, enveloppez simplement votre formule CHOISIR dans la fonction « SIERREUR » comme suit :
=SIERREUR(CHOISIR((B2> 0) + (B2> = 51) + (B2> = 101) + (B2> = 151); "Faible"; "Satisfaisant"; "Bien"; "Excellent"); " ")
Ainsi, lorsque votre formule CHOISIR revoie une telle erreur, la fonction SIERREUR la remplace par une chaine vide.
Effectuer différents calculs en fonction d’une condition
De la même manière, vous pouvez utiliser la fonction Excel CHOISIR pour effectuer un calcul dans une série de calculs/formules possibles sans avoir à imbriquer plusieurs instructions SI les unes dans les autres.
Prenons un exemple pour mieux comprendre le principe. Dans la capture d’écran ci-dessous, nous avons une liste de vendeurs dans la colonne A et leurs ventes dans la colonne B :
Nous souhaitons calculer la commission de chaque vendeur en fonction de ses ventes selon les conditions ci-dessous :
- Ventes entre 0 et 500 : commission de 5%.
- Ventes entre 501 et 1000 : commission de 7%.
- Ventes plus de 1001 : commission de 10%.
Avec le montant des ventes dans la colonne B2, la formule à utiliser est comme suit :
=CHOISIR((B2> 0) + (B2> = 501) + (B2> = 1001); B2 * 5%; B2 * 7%; B2 * 10%)
Tout comme dans l’exemple précédent, vous pouvez utiliser les références de cellules au lieu de coder en dur les pourcentages dans la formule pour rendre votre formule plus flexible. Mettons les pourcentages des commissions dans une plage de cellules (F2:F4 dans cet exemple) pour les utiliser comme références. N'oubliez pas de fixer les références en utilisant le signe $.
=CHOISIR((B2>0)+(B2>501)+(B2>1001); B2 * $F$2; B2 * $F$3; B2 * $F$4)
Après avoir appliqué la formule sur les autres cellules, nous obtenons le résultat ci-dessous :
Si vous souhaitez garder uniquement les valeurs, vous pouvez convertir toutes les formules en valeurs. Vous avez deux méthodes pour le faire :
- Utilisation de l’option « Valeurs avec mise en formats des nombres » dans le menu contextuel ;
- Ou en utilisant l’option « Valeurs » de la boîte de dialogue « Collage spécial ».
Pour ce faire, copiez d’abord les cellules ou les plages (C2:C6 dans cet exemple) avec la formule en utilisant le raccourci Ctrl + C.
Ensuite, faites un clic-droit dessus et sélectionnez « Collage spécial » dans le menu contextuel. Vous allez voir apparaitre un autre menu, sélectionnez cette fois-ci l’option « Valeurs avec mise en formats des nombres » comme illustré ci-dessous :
Exemple 3 : utiliser la fonction CHOISIR pour faire une RECHERCHEV gauche
Comme vous pouvez le savoir, la formule RECHERCHEV inversée dans Excel est utilisée pour faire une recherche verticale à gauche et est une formule utile dans l'analyse des données.
En général, la fonction RECHERCHEV recherche la valeur uniquement vers la droite. Cependant, en l’utilisant en combinaison avec la fonction CHOISIR, elle peut rechercher dans les deux directions à partir de la colonne de recherche (RECHERCHEV vers la gauche et RECHERCHEV vers la droite). Cette fonctionnalité dans Excel est appelée recherche bidirectionnelle.
Ces deux fonctions imbriquées, capables de récupérer des valeurs à gauche de la colonne de recherche, sont appelées recherche inversée ou recherche arrière, ce qui signifie qu'une recherche inversée fait partie de la recherche bidirectionnelle.
La formule imbriquée RECHERCHEV et CHOISIR est plus flexible que RECHERCHEV.
Prenons l’exemple ci-dessous :
Nous avons une liste de scores dans la colonne A et les noms des élèves dans la colonne B, et nous souhaitons retourner le score d'un élève particulier.
Puisque la colonne de retour « Score » se trouve à gauche de la colonne de recherche « Elève », la formule RECHERCHEV régulière renvoie l'erreur « #N/A » comme indiqué ci-dessus.
Pour résoudre ce problème, nous allons utiliser la fonction CHOISIR pour permuter les positions des colonnes comme suit :
=CHOISIR({1.2}; B2:B10; A2:A10)
En effet, cette formule indique à Excel que la colonne 1 est « B » et la colonne 2 est « A ».
Maintenant, il nous reste d’intégrer la formule ci-dessus dans l'argument « table_matrice » de la fonction RECHERCHEV comme suit :
=RECHERCHEV(E1; CHOISIR({1.2}; B2:B10; A2:A10); 2; FAUX)
Et voilà, une recherche à gauche est effectuée sans difficultés ni erreurs !
Remarque :
Notez que nous avons donné ici des plages de cellules dans les arguments de valeurs et la fonction CHOISIR les a acceptés (normalement, elle n’accepte pas les plages de cellules). En effet, c’est parce que nous avons fourni un tableau de {1.2} dans l'argument « no_index » que la fonction CHOISIR les a acceptés.
Conclusion
Nous avons traité un vaste éventail de scénarios auxquels nous pouvons appliquer la fonction « CHOISIR ». Cela vous donne une large perspective sur la façon dont nous pouvons utiliser cette fonction afin de résoudre diverses situations. Excel offre tellement d'outils et de fonctions que le même problème peut souvent être résolu à partir d'une variété de stratégies. C'était un aperçu de la façon dont la fonction « CHOISIR » peut vous aider à surmonter différents problèmes de manière efficace (et simple !).